023bf6f1b8
Discarded sections in different archs share some commonality but have considerable differences. This led to linker script for each arch implementing its own /DISCARD/ definition, which makes maintaining tedious and adding new entries error-prone. This patch makes all linker scripts to move discard definitions to the end of the linker script and use the common DISCARDS macro. As ld uses the first matching section definition, archs can include default discarded sections by including them earlier in the linker script. ia64 is notable because it first throws away some ia64 specific subsections and then include the rest of the sections into the final image, so those sections must be discarded before the inclusion. defconfig compile tested for x86, x86-64, powerpc, powerpc64, ia64, alpha, sparc, sparc64 and s390. Michal Simek tested microblaze. Signed-off-by: Tejun Heo <tj@kernel.org> Acked-by: Paul Mundt <lethal@linux-sh.org> Acked-by: Mike Frysinger <vapier@gentoo.org> Tested-by: Michal Simek <monstr@monstr.eu> Cc: linux-arch@vger.kernel.org Cc: Michal Simek <monstr@monstr.eu> Cc: microblaze-uclinux@itee.uq.edu.au Cc: Sam Ravnborg <sam@ravnborg.org> Cc: Tony Luck <tony.luck@intel.com>
199 lines
4 KiB
ArmAsm
199 lines
4 KiB
ArmAsm
/*
|
|
* vmlinux.lds.S -- master linker script for m68knommu arch
|
|
*
|
|
* (C) Copyright 2002-2006, Greg Ungerer <gerg@snapgear.com>
|
|
*
|
|
* This linker script is equiped to build either ROM loaded or RAM
|
|
* run kernels.
|
|
*/
|
|
|
|
#include <asm-generic/vmlinux.lds.h>
|
|
|
|
#if defined(CONFIG_RAMKERNEL)
|
|
#define RAM_START CONFIG_KERNELBASE
|
|
#define RAM_LENGTH (CONFIG_RAMBASE + CONFIG_RAMSIZE - CONFIG_KERNELBASE)
|
|
#define TEXT ram
|
|
#define DATA ram
|
|
#define INIT ram
|
|
#define BSS ram
|
|
#endif
|
|
#if defined(CONFIG_ROMKERNEL) || defined(CONFIG_HIMEMKERNEL)
|
|
#define RAM_START CONFIG_RAMBASE
|
|
#define RAM_LENGTH CONFIG_RAMSIZE
|
|
#define ROMVEC_START CONFIG_ROMVEC
|
|
#define ROMVEC_LENGTH CONFIG_ROMVECSIZE
|
|
#define ROM_START CONFIG_ROMSTART
|
|
#define ROM_LENGTH CONFIG_ROMSIZE
|
|
#define TEXT rom
|
|
#define DATA ram
|
|
#define INIT ram
|
|
#define BSS ram
|
|
#endif
|
|
|
|
#ifndef DATA_ADDR
|
|
#define DATA_ADDR
|
|
#endif
|
|
|
|
|
|
OUTPUT_ARCH(m68k)
|
|
ENTRY(_start)
|
|
|
|
MEMORY {
|
|
ram : ORIGIN = RAM_START, LENGTH = RAM_LENGTH
|
|
#ifdef ROM_START
|
|
romvec : ORIGIN = ROMVEC_START, LENGTH = ROMVEC_LENGTH
|
|
rom : ORIGIN = ROM_START, LENGTH = ROM_LENGTH
|
|
#endif
|
|
}
|
|
|
|
jiffies = jiffies_64 + 4;
|
|
|
|
SECTIONS {
|
|
|
|
#ifdef ROMVEC_START
|
|
. = ROMVEC_START ;
|
|
.romvec : {
|
|
__rom_start = . ;
|
|
_romvec = .;
|
|
*(.data.initvect)
|
|
} > romvec
|
|
#endif
|
|
|
|
.text : {
|
|
_text = .;
|
|
_stext = . ;
|
|
HEAD_TEXT
|
|
TEXT_TEXT
|
|
SCHED_TEXT
|
|
LOCK_TEXT
|
|
*(.text.lock)
|
|
|
|
. = ALIGN(16); /* Exception table */
|
|
__start___ex_table = .;
|
|
*(__ex_table)
|
|
__stop___ex_table = .;
|
|
|
|
*(.rodata) *(.rodata.*)
|
|
*(__vermagic) /* Kernel version magic */
|
|
*(__markers_strings)
|
|
*(.rodata1)
|
|
*(.rodata.str1.1)
|
|
|
|
/* Kernel symbol table: Normal symbols */
|
|
. = ALIGN(4);
|
|
__start___ksymtab = .;
|
|
*(__ksymtab)
|
|
__stop___ksymtab = .;
|
|
|
|
/* Kernel symbol table: GPL-only symbols */
|
|
__start___ksymtab_gpl = .;
|
|
*(__ksymtab_gpl)
|
|
__stop___ksymtab_gpl = .;
|
|
|
|
/* Kernel symbol table: Normal unused symbols */
|
|
__start___ksymtab_unused = .;
|
|
*(__ksymtab_unused)
|
|
__stop___ksymtab_unused = .;
|
|
|
|
/* Kernel symbol table: GPL-only unused symbols */
|
|
__start___ksymtab_unused_gpl = .;
|
|
*(__ksymtab_unused_gpl)
|
|
__stop___ksymtab_unused_gpl = .;
|
|
|
|
/* Kernel symbol table: GPL-future symbols */
|
|
__start___ksymtab_gpl_future = .;
|
|
*(__ksymtab_gpl_future)
|
|
__stop___ksymtab_gpl_future = .;
|
|
|
|
/* Kernel symbol table: Normal symbols */
|
|
__start___kcrctab = .;
|
|
*(__kcrctab)
|
|
__stop___kcrctab = .;
|
|
|
|
/* Kernel symbol table: GPL-only symbols */
|
|
__start___kcrctab_gpl = .;
|
|
*(__kcrctab_gpl)
|
|
__stop___kcrctab_gpl = .;
|
|
|
|
/* Kernel symbol table: Normal unused symbols */
|
|
__start___kcrctab_unused = .;
|
|
*(__kcrctab_unused)
|
|
__stop___kcrctab_unused = .;
|
|
|
|
/* Kernel symbol table: GPL-only unused symbols */
|
|
__start___kcrctab_unused_gpl = .;
|
|
*(__kcrctab_unused_gpl)
|
|
__stop___kcrctab_unused_gpl = .;
|
|
|
|
/* Kernel symbol table: GPL-future symbols */
|
|
__start___kcrctab_gpl_future = .;
|
|
*(__kcrctab_gpl_future)
|
|
__stop___kcrctab_gpl_future = .;
|
|
|
|
/* Kernel symbol table: strings */
|
|
*(__ksymtab_strings)
|
|
|
|
/* Built-in module parameters */
|
|
. = ALIGN(4) ;
|
|
__start___param = .;
|
|
*(__param)
|
|
__stop___param = .;
|
|
|
|
. = ALIGN(4) ;
|
|
_etext = . ;
|
|
} > TEXT
|
|
|
|
.data DATA_ADDR : {
|
|
. = ALIGN(4);
|
|
_sdata = . ;
|
|
DATA_DATA
|
|
. = ALIGN(32);
|
|
*(.data.cacheline_aligned)
|
|
. = ALIGN(8192) ;
|
|
*(.data.init_task)
|
|
_edata = . ;
|
|
} > DATA
|
|
|
|
.init : {
|
|
. = ALIGN(4096);
|
|
__init_begin = .;
|
|
_sinittext = .;
|
|
INIT_TEXT
|
|
_einittext = .;
|
|
INIT_DATA
|
|
. = ALIGN(16);
|
|
__setup_start = .;
|
|
*(.init.setup)
|
|
__setup_end = .;
|
|
__initcall_start = .;
|
|
INITCALLS
|
|
__initcall_end = .;
|
|
__con_initcall_start = .;
|
|
*(.con_initcall.init)
|
|
__con_initcall_end = .;
|
|
__security_initcall_start = .;
|
|
*(.security_initcall.init)
|
|
__security_initcall_end = .;
|
|
#ifdef CONFIG_BLK_DEV_INITRD
|
|
. = ALIGN(4);
|
|
__initramfs_start = .;
|
|
*(.init.ramfs)
|
|
__initramfs_end = .;
|
|
#endif
|
|
. = ALIGN(4096);
|
|
__init_end = .;
|
|
} > INIT
|
|
|
|
.bss : {
|
|
. = ALIGN(4);
|
|
_sbss = . ;
|
|
*(.bss)
|
|
*(COMMON)
|
|
. = ALIGN(4) ;
|
|
_ebss = . ;
|
|
_end = . ;
|
|
} > BSS
|
|
|
|
DISCARDS
|
|
}
|
|
|