{ config, pkgs, lib, modulesPath, ... }:

{
  disabledModules = [
    # tries to instantiate 32-bit pkgs
    (modulesPath + "/config/ldso.nix")
    (modulesPath + "/programs/nix-ld.nix")
    (modulesPath + "/config/stub-ld.nix")
  ];
  config = lib.mkMerge [
    (lib.mkIf config.nixpkgs.buildPlatform.isMusl {
      nixpkgs.overlays = [ (import ./overlay.nix) ];
    })
    (lib.mkIf config.nixpkgs.hostPlatform.isMusl {

      programs.steam.enable = lib.mkForce false;
      services.pipewire.alsa.support32Bit = lib.mkForce false;
      programs.mosh.withUtempter = lib.mkForce false;
      programs.tmux.withUtempter = lib.mkForce false;

      networking.nftables.checkRuleset = false; # lkl is broken :/

      services.nscd.enable = false;
      system.nssModules = lib.mkForce [ ];

      i18n.glibcLocales = pkgs.callPackage
        (pkgs.path + "/pkgs/development/libraries/glibc/locales.nix") {
          allLocales = false;
        };

      security.pam.services.login.updateWtmp =
        lib.mkForce false; # fixes pam errors

      # service fails to start otherwise "Function not implemented"
      systemd.services.nix-daemon.serviceConfig = {
        CPUSchedulingPolicy = lib.mkForce null;
        IOSchedulingClass = lib.mkForce null;
        IOSchedulingPriority = lib.mkForce null;
      };

      programs.less.lessopen = null;
    })
  ];
}